D7net Mini Sh3LL v1
Current File : //libx32/../share/snapd/../locale/ia/../../doc/info/../libroken18-heimdal/../usbmuxd/../liberror-perl/../grub2-common/../libjpeg8/../php7.4-mysql/../gnupg/../python3-apt/../netplan.io/../wget/../libcurl3-gnutls/../libthai-data/../python3-six/../screen/../maria/../libxaw7/../libmnl0/../netplan/../gdisk/../systemd-sysv/../grep/../udisks2/../libacl1/../libxmlb1/../libperl5.30/../automake/../libmpfr6/../libssl1.1/../btrfs-progs/../usbutils/../tcpdump/../libsemanage1/../libdrm2/../gcc/../libselinux1/../bzip2/../mtr-tiny/../iw/../apport/../accountsservice/../bolt/../liblzma5/../libmpfr6/../dbus/../libblockdev-loop2/../cryptsetup-bin/../bcache-tools/../bzip2/../systemd/../libmagic-mgc/../mariadb-client-10.3/../../iptables/../aclocal-1.16/silent.m4 |
## -*- Autoconf -*-
# Copyright (C) 2009-2018 Free Software Foundation, Inc.
#
# This file is free software; the Free Software Foundation
# gives unlimited permission to copy and/or distribute it,
# with or without modifications, as long as this notice is preserved.
# AM_SILENT_RULES([DEFAULT])
# --------------------------
# Enable less verbose build rules; with the default set to DEFAULT
# ("yes" being less verbose, "no" or empty being verbose).
AC_DEFUN([AM_SILENT_RULES],
[AC_ARG_ENABLE([silent-rules], [dnl
AS_HELP_STRING(
[--enable-silent-rules],
[less verbose build output (undo: "make V=1")])
AS_HELP_STRING(
[--disable-silent-rules],
[verbose build output (undo: "make V=0")])dnl
])
case $enable_silent_rules in @%:@ (((
yes) AM_DEFAULT_VERBOSITY=0;;
no) AM_DEFAULT_VERBOSITY=1;;
*) AM_DEFAULT_VERBOSITY=m4_if([$1], [yes], [0], [1]);;
esac
dnl
dnl A few 'make' implementations (e.g., NonStop OS and NextStep)
dnl do not support nested variable expansions.
dnl See automake bug#9928 and bug#10237.
am_make=${MAKE-make}
AC_CACHE_CHECK([whether $am_make supports nested variables],
[am_cv_make_support_nested_variables],
[if AS_ECHO([['TRUE=$(BAR$(V))
BAR0=false
BAR1=true
V=1
am__doit:
@$(TRUE)
.PHONY: am__doit']]) | $am_make -f - >/dev/null 2>&1; then
am_cv_make_support_nested_variables=yes
else
am_cv_make_support_nested_variables=no
fi])
if test $am_cv_make_support_nested_variables = yes; then
dnl Using '$V' instead of '$(V)' breaks IRIX make.
AM_V='$(V)'
AM_DEFAULT_V='$(AM_DEFAULT_VERBOSITY)'
else
AM_V=$AM_DEFAULT_VERBOSITY
AM_DEFAULT_V=$AM_DEFAULT_VERBOSITY
fi
AC_SUBST([AM_V])dnl
AM_SUBST_NOTMAKE([AM_V])dnl
AC_SUBST([AM_DEFAULT_V])dnl
AM_SUBST_NOTMAKE([AM_DEFAULT_V])dnl
AC_SUBST([AM_DEFAULT_VERBOSITY])dnl
AM_BACKSLASH='\'
AC_SUBST([AM_BACKSLASH])dnl
_AM_SUBST_NOTMAKE([AM_BACKSLASH])dnl
])
AnonSec - 2021 | Recode By D7net